vb 串口通信编程
一、概述
串口通讯作为一种古老而又灵活的通讯方式,被广泛地应用于PC间的通讯以及 PC和单
片机之间的通讯之中。 提到串口通讯的编程,人们往往立刻想到C、汇编等对系统底层操
作支持较好的编程语言以及大串繁琐的代码。
实际上,只要我们借助相关ActiveX 控件的帮助,即使是在底层操作一向不被人看好的VB
中,一样能够实现串口通 讯,甚至其实现方法和 C、汇编相比,要更加快捷方便。下面,
笔者就介绍一下在VB中实现串口通讯的方法。
在 Visual Basic 中有一个名为 Microsoft Communication Control(简称MSComm)的通讯控
件。我们只要通 过对此控件的属性和事件进行相应编程操作,就可以轻松地实现串口通讯。
下面,笔者就简要地介绍一下
MSComm 控件的使用方法。
二、MSComm 控件的主要属性、事件
1、MSComm 的属性
由于MSComm 控件属性很多,在此笔者仅介绍与实现串口通讯密切相关的核心属性。
Commport:设置通讯所占用的串口号。如设成 1(默认值),
表
关于同志近三年现实表现材料材料类招标技术评分表图表与交易pdf视力表打印pdf用图表说话 pdf
示对Com1 进行操作。
Setting:对串口通讯的相关参数。包括串口通讯的比特率,奇偶校验,数据位长度、停止
位等。其默认值 是“9600,N,8,1”,表示串口比特率是 9600bit/s,不作奇偶校验,8 位数据
位,1个停止位。
Portopen:设置串口状态,值为 True时打开串口,值为False 时关闭串口。
Input:从输入寄存器读取数据,返回值为从串口读取的数据
内容
财务内部控制制度的内容财务内部控制制度的内容人员招聘与配置的内容项目成本控制的内容消防安全演练内容
,同时输入寄存器将被
清空。
Ouput:发送数据到输出寄存器。
InBufferCount:设置输入寄存器所存储的字符数,当将其值设为0 时,则输入寄存器将被
清空。
InputMode:设置从输入寄存器中读取数据的形式。若值为 0,则表示以文本形式读取;
值为 1,则表示以 二进制形式读取。
OutBufferCount:设置输出寄存器所存储的字符数,当将其值设为 0时,则输出寄存器将
被清空。
RThreshold:设置在MSComm 控件设置CommEvent 属性为 comEvReceive 并产生OnComm
事件之前要接受的字符 数。
CommEvent 属性:返回最近的通讯事件或错误。通过对它具体属性值的查询,我们就可
以获得通讯事件和通 讯错误的完整信息。当其值是comEvReceive 时表示接收到数据。
2、MSComm 的事件
除了公共事件之外,MSComm 只有一个OnComm 事件。当CommEvent 属性值变化时将发
生 OnComm 事件,指示发生 一个通讯事件或错误。当我们设置Rtheshold 属性值为 0 时,将
使得捕获 comEvReceive 事件无效。
三、串口通讯编程实例
在完成了对 MSComm 控件的简要介绍之后,笔者就以实际程序为例,介绍一下串口通讯
的具体实现方法。
1、PC 机间的串口通讯
(1)、实现方法:
A、新建一个窗体,在上面放两个Text 控件、两个CommandButton 控件和两个Label 控件
(如图 1.bmp 所示)。
具体见下表:
控件类型 名称 Caption 属性 作用
-------------------------------------------------------------------------------
Text Text1 ------- 输入所要发送的信息
Text Text2 ------- 显示接收到的信息
CommandButton Command1 发 送 ---------
CommandButton Command2 退 出 ---------
Label Label1 发送的数据 提示
Label Label2 接收的数据 提示
B、在控件工具箱中的空白处点击鼠标右键,在弹出的菜单中选择“部件”,在弹出的窗
口中的控件列表中 找到“Microsoft Comm Control”,将其选中,在点击“应用”、“关闭”,
在控件工具栏中就会出现一个电 话的小图标。
C、用串口线将两台电脑连接起来。您可以使用Com1对 Com1的对应连接,也可以使用
Com1和 Com2 的交叉连接。
本程序使用的是Com1 对 Com1的连接。
D、输入以下代码:
Private Sub Command1_Click()
'...发送数据
MSComm1.OutBufferCount = 0 '...清空输出寄存器
MSComm1.Output = Text1.Text '...发送数据
End Sub
Private Sub Command2_Click()
'...退出
Unload Me
End Sub
Private Sub Form_Load()
'...初始化
MSComm1.CommPort = 1 '...使用 Com1口
MSComm1.Settings = "9600,n,8,1" '...设置通讯参数
MSComm1.PortOpen = True '...打开串口
End Sub
Private Sub Mscomm1_Oncomm()
'...通讯事件发生
Select Case MSComm1.CommEvent
Case comEvReceive '...有接受事件发生
Text2.Text = MSComm1.Input '...接受显示数据
MSComm1.InBufferCount = 0 '...清空输入寄存器
End Select
End Sub
2、PC 机与单片机之间的通讯
PC机与单片机之间的通讯被广泛的用于工业、医疗测控等领域之中。在应用中,我们通
常将单片机作为“感 受器”和“效应器”,负责数据采集、响应计算机发出的指令对电路
进行控制,有时也进行一些简单的运算, 最后再将执行数据反馈给计算机处理。本程序将
实现在PC 机上输入一个 0-255 之间的整数,将此数据发送到单片 机,单片机接收到数据后 ,
将数据在显示管上显示,再将此数除以 2,将得数返回给PC机。(运行效果如图 3.BMP 所
示)其实现方法如下:
A、同 PC机间通讯的实现方法A-B。
B、连接电脑和单片机。注意!由于PC 机端的RS232 电平与单片机端TTL 的并不不匹配 ,
故应注意电平转换。
C、在 VB中输入以下代码:
Private Sub Mscomm1_Oncomm()
'...通讯事件发生
Dim indata As Variant
Dim bte(0) As Byte
Select Case MSComm1.CommEvent
Case comEvReceive '...有接受事件发生
indata = MSComm1.Input
'...注意!要通过 MSComm 控件发送或接收二进制数据必须用Variant 类型的变量对二进
'...制 Byte 类型的变量进行转换!
bte(0) = AscB(indata)
Text2.Text = bte(0)
MSComm1.InBufferCount = 0 '...清空输入寄存器
End Select
End Sub
Private Sub Command1_Click()
'...发送数据
Dim Num As Integer
Dim outbte(0) As Byte
Num = Val(Text1.Text)
outbte(0) = CByte(Num)
MSComm1.OutBufferCount = 0 '...清空输出寄存器
MSComm1.Output = outbte(0) '...发送数据
End Sub
Private Sub Command2_Click()
'...退出
Unload Me
End Sub
Private Sub Form_Load()
'...初始化
MSComm1.CommPort = 1 '...使用 Com1口
MSComm1.Settings = "9600,n,8,1" '...设置通讯参数
MSComm1.PortOpen = True '...打开串口
End Sub
D、单片机工作方式置于 1,比特率设为 9600bit/s。在单片机上,我们只得使用汇编语言
编写,并且调用中 断实现对串口数据的收发工作。源代码如下:
PUSH PSW ;将程序状态字压入堆栈
PUSH ACC ;将累加器压入堆栈
CLR EA ;关闭系统中断
CLR RI ;清除中断标志位
MOV A,SBUF ;从接收寄存器中读取数据
MOV 70H,A ;分解数据百、十、个位并显示
MOV B,#100
DIV AB
MOV 52H,A ;分解百位,送入存储器 52H
MOV A,B
MOV B,#10
DIV AB
MOV 51H,A ;分解十位,送入存储器 51H
MOV 50H,B ;分解个位,送入存储器 50H
MOV A,70H
MOV B,#2
DIV AB ;将接受的数据除以 2
MOV SBUF,A ;将得数发送到输出寄存器
ACALL DL1 ;延时保证数据完整发送
ACALL DL1
CLR RI ;清除中断标志位
SETB EA ;打开系统中断
POP ACC ;累加器出栈
POP PSW ;程序状态字出栈
RETI ;中断程序返回
3、编程环境
以上程序在Windows 2000 Professional,Visual Basic 6.0 企业版,AT89C52 型单片机下调
试通过。
四、总结
从以上程序可以看出,在VB中利用MSComm 控件,可以快速开发出串口通讯程序,从
而大大提高编程效率